/*
 * Copyright (c) 2021 AtLarge Research
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in all
 * copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
 * SOFTWARE.
 */

import org.gradle.api.distribution.DistributionContainer


plugins {
    distribution
}

tasks.named("assembleDist") {
    val tasks = getTasksByName("assembleDist", true).filter { it.project != project }
    dependsOn(tasks)
}

distributions {
    main {
        contents {
            duplicatesStrategy = DuplicatesStrategy.EXCLUDE

            from("README.md")
            from("LICENSE.txt")
            from("docs") { into("docs") }

            // Include distributions of the subprojects
            getTasksByName("assembleDist", true)
                .filter { it.project != project }
                .map { it.project.name to it.project.the<DistributionContainer>() }
                .forEach { (name, dist) ->
                    dist.findByName("main")?.let { with(it.contents) }

                    // Include experiments if they exist
                    val experiment = dist.findByName("experiment")
                    if (experiment != null) {
                        into("experiments/${name.removePrefix("opendc-experiments-")}") {
                            with(experiment.contents)
                        }
                    }
                }
        }
    }
}